Set oShell = WScript.CreateObject("WScript.Shell") 
Set objSysInfo = CreateObject("ADSystemInfo") 
Set objDC = GetObject("LDAP://" & objSysInfo.ComputerName) 
Set oFilesystem = CreateObject("Scripting.FileSystemObject") 
sGUID = objDC.GUID 
sDNShostname = objDC.DNShostname 
sHostname = objDC.cn

sDCCRFilename = "DomainControllerCertRequest-" & sHostname & ".req"

' Remove old request
If oFilesystem.FileExists(sDCCRFilename) = True Then
  oFilesystem.DeleteFile(sDCCRFilename)
End If

sGeneratingScriptName = "ReqDCCert.vbs"

If oFilesystem.FileExists(sGeneratingScriptName) = False Then
  Wscript.Echo "Could not find required script " & sGeneratingScriptName & "."
  Wscript.Quit 1
End If

oShell.Run sGeneratingScriptName, 0, True
oShell.Run "certreq -new " & sHostname & ".inf " & sDCCRFilename, 0, True

' Clean up unused files
If oFilesystem.FileExists(sHostname & "-vfy.bat") = True Then
  oFilesystem.DeleteFile(sHostname & "-vfy.bat")
  oFilesystem.DeleteFile(sHostname & "-req.bat")
  oFilesystem.DeleteFile(sHostname & ".asn")
  oFilesystem.DeleteFile(sHostname & ".bin")
  oFilesystem.DeleteFile(sHostname & ".b64")
  oFilesystem.DeleteFile(sHostname & ".inf")
End If

Set oFile = oFilesystem.CreateTextFile("DomainControllerInfo-" & sHostname & ".txt") 
oFile.WriteLine "Host name: " & sHostname
oFile.WriteLine "GUID: " & sGUID
oFile.WriteLine "DNS hostname: " & sDNShostname
oFile.Close 

Wscript.Echo "Done!"